Excel加载项COM编写过程（工具栏响应）

步骤：

一、创建工程并设置属性
二、连接Excel
三、响应Excel事件
四、调试编译分发安装

一、创建工程并设置属性。

1、新建工程：打开VB6.0，新建一个工程。在新建工程选项中选择“外接程序”（有的是“Addin”）。

2、为工程添加引用：“工程”菜单“引用”勾上“Microsoft Excel 11.0 Object Libray”。（如果不引用，ExcelApplication、工具栏、按钮需声明为“Object”，且代码编写过程中没有自动完成对象的属性、方法等）
3、设置设计器属性：在工程资源管理器中双击“Connect（Connect）”，打开设计器设计窗口。

在设计器中。外接程序显示名称输入你想要的名称（这里为“TestAddin”）；外接程序描述中输入外接程序的描述；应用程序选择“Microsoft Excel”；应该程序版本取决于你的电脑装了什么版本的Office我装的是Office2003，故选“Microsoft Excel 11.0”；初始化加载行为选择“Startup”。

二、连接 Excel

我们编写COM加载项就是要在Excel里面做点什么，如果用一个变量来保存Excel对象的话，我们基本上就能任意把Excel捏圆捏扁。变量的作用域是作为模块级的还是全局的就看你的实际情况，为了方便，这里定义为全局变量。添加一个模块“mduMain”，在模块中定义变量：

Public gExcelApp As Excel.Application。

连接Excel对象
双击设计器“Connect”，按“F7”进入代码编辑窗口，把除了“Option Explicit”之外的代码都删除。在“对象框”中选择“AddinInstance”，“过程/事件框”中选择“OnConnection”。

即出现

Private Sub AddinInstance_OnConnection(ByVal Application As Object, ByVal ConnectMode As AddInDesignerObjects.ext_ConnectMode, ByVal AddInInst As Object, custom() As Variant)
End Sub

在该过程中写入“Set gExcelApp = Application”

Private Sub AddinInstance_OnConnection(ByVal Application As Object, ByVal ConnectMode As AddInDesignerObjects.ext_ConnectMode, ByVal AddInInst As Object, custom() As Variant)
Set gExcelApp = Application
End Sub

定义用来响应按钮事件的类，以便添加工具栏过程中使用。

添加一个类“ButtonEvent”，在类中定义一个响应事件的变量。

Public WithEvents Button As Office.CommandBarButton

如果事先知道有多少个按钮的话，可以用类数组。为了更好的扩展性，这里用一个集合类“ButtonEventCol”来管理“ButtonEvent”类。
添加一个类“ButtonEventCol”，“ButtonEventCol”类的代码：

Option Explicit
Private mCol As Collection '集合，用来存放“ButtonEvent”类。
Private Sub Class_Initialize()
    Set mCol = New Collection '类实例化时实例化集合
End Sub
Private Sub Class_Terminate()
    Set mCol = Nothing '类销毁时销毁集合
End Sub
Public Sub Add(ByRef Button As Office.CommandBarButton) '添加按钮

    Dim objNew As New ButtonEvent '创建“ButtonEvent”类新实例

    Set objNew.Button = Button '连接事件
    mCol.Add objNew '将类添加到集合中，只要“ButtonEventCol”类生存期未完，所有添加的“ButtonEvent”类就一直生存。
    Set objNew = Nothing
End Sub

创建工具栏和按钮

双击设计器“Connect”，按“F7”进入代码编辑窗口。刚才我们的代码

已经在 OnConnection 事件中连接 Excel 对象。我们就用“gExcelApp”这个对象变量来创建工具栏和按钮，并与响应事件的类连接。

'定义一个变量用于存放工具栏对象。
Private mMyBar As Office.CommandBar

'定义一个变量用于存放“ButtonEventCol”类实例
Private mButtonEventCol As New ButtonEventCol

假设我们在Excel创建一个名叫“外接程序”的工具栏，工具栏中有二个按钮，分别为：“新建工作簿”、“关闭工作簿”。
在“AddinInstance_OnStartupComplete”（对象已加载完毕）事件中创建工具栏、按钮，并把按钮和响应事件的类连接，代码如下：

Private Sub AddinInstance_OnStartupComplete(custom() As Variant)
    Dim MyControl As Office.CommandBarButton
    Set mMyBar = gExcelApp.CommandBars.Add(Name:="外接程序", Position:=msoBarFloating, Temporary:=True)
    mMyBar.Visible = True
    Set MyControl = mMyBar.Controls.Add(Type:=msoControlButton, Temporary:=True)
    With MyControl
        .BeginGroup = False
        .Caption = "新建工作簿"
        .Enabled = True
        .Visible = True
        .FaceId = 18
        .Style = msoButtonIconAndCaption
        .Parameter = "New" 'Parameter 属性是类在响应按钮事件时区分按钮的标记。
        '如果用 Tag 属性来区分的话，会发生二次事件。不知道为什么。
    End With
    mButtonEventCol.Add MyControl
    Set MyControl = mMyBar.Controls.Add(Type:=msoControlButton, Temporary:=True)
    With MyControl
        .BeginGroup = False
        .Caption = "关闭工作簿"
        .Enabled = True
        .Visible = True
        .FaceId = 1088
        .Style = msoButtonIconAndCaption
        .Parameter = "Close"
    End With
    mButtonEventCol.Add MyControl
    Set MyControl = Nothing
End Sub

关闭 Excel 时执行

Private Sub AddinInstance_OnBeginShutdown(custom() As Variant)
    Set mButtonEventCol = Nothing
    '关闭 Excel 时释放类。
    '因为工具栏、按钮在创建的时候已经把 Temporary 属性设为 True 了，关闭 Excel 自动删除。
    '所以这里不用编写删除工具栏的代码。
End Sub

三、响应按钮的事件

打开类“ButtonEvent”的代码编辑窗口，添加事件过程

Private Sub Button_Click(ByVal Ctrl As Office.CommandBarButton, CancelDefault As Boolean)
End Sub

在该事件过程中添加代码如下：

Private Sub Button_Click(ByVal Ctrl As Office.CommandBarButton, CancelDefault As Boolean)
    Select Case Ctrl.Parameter '根据按钮的 Parameter 属性决定执行什么动作。
        Case "New"
            gExcelApp.Workbooks.Add
        Case "Close"
            If Not (gExcelApp.ActiveWorkbook Is Nothing) Then
                gExcelApp.ActiveWorkbook.Close
            Else
                MsgBox "没有活动工作簿", vbExclamation
            End If
    End Select
End Sub

四、调试编译分发安装

1、调试和编译：

关闭Excel，设计器代码窗口中的“AddinInstance_OnConnection”事件中，在“Set gExcelApp = Application”这句代码设置断点。按“F5”运行，然后打开 Excel 。这时，代码执行到“Set gExcelApp = Application”这里就暂停了。你可以一步一步按“F8”进行跟踪调试，看看加载项的工作方法，找到错误的地方并改正。当调试没什么问题之后，编译就比较简单了，按“文件”菜单“生成工具栏连接.DLL”。然后生成就行了。

2、分发安装

这里介绍用“WinRAR”制作安装包。
按“工程”菜单引用，查看引用项目的路径，把引用项目的文件复制到生成的DLL文件目录中。
如果有窗体，在工具栏点右建“部件”，查看引用的项目的路径，把引用项目的文件复制到生成的DLL文件目录中。
打开“记事本”，输入

RegSvr32.exe 工具栏连接.dll

。另存为，保存类型选“所有文件”，文件名“安装.BAT”，保存到生成的DLL文件目录中。
打开“记事本”，输入

RegSvr32.exe 工具栏连接.dll /U

。另存为，保存类型选“所有文件”，文件名“卸载.BAT”，保存到生成的DLL文件目录中。
打开“WinRAR”，定位到生成的DLL文件的目录。选中要DLL文件、安装和卸载两个BAT文件、被工程引用项目的文件等。按“添加”。